ESP8266 – ESP8266WebServer库 – authenticate

位置导航: ESP8266库 / ESP8266WebServer库 / 本页

说明

我们在使用ESP8266开发板实现物联网服务器时，可以通过本函数建立加密网页。也就是说，用户必须正确输入访问用户名和密码方可访问物联网服务器所建立的页面内容。

请注意，与此函数配套使用的是requestAuthentication函数。requestAuthentication函数用于向客户端发送认证请求，而authenticate函数用于设置与校验客户端请求信息中的用户名和密码。

语法

authenticate(username, password)

参数

username：客户端访问物联网服务器加密页面时的认证用户名（参数类型:const char*）

password：客户端访问物联网服务器加密页面时的认证密码（参数类型:const char*）

返回值

如果用户密码输入正确则返回真,输入错误则返回假。

示例程序

当您将WiFi连接信息修改后并且将本示例程序上传ESP8266开发板后，开发板随即会自动连接WiFi。WiFi连接成功后，您将可以从串口监视器获取当前ESP8266开发板的IP。

接下来您可以通过浏览器地址栏输入ESP8266开发板的IP地址并键入回车（即向ESP8266开发板所建立的物联网服务器发送一个GET请求）。

接下来浏览器将会弹出对话框，要求用户输入用户名:TaichiMaker和密码:123456。如下图所示。

只有当用户正确输入了用户名和密码信息以后，方可打开ESP8266开发板建立的网站页面。（如下图所示）

以下示例程序中的高亮语句server.authenticate("TaichiMaker", "123456")设置了服务器的访问用户名和密码信息。

/**********************************************************************
  项目名称/Project          : 零基础入门学用物联网
  程序名称/Program name     : WebServer_demo_authenticate
  团队/Team                : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)
  作者/Author              : Dapenson
  日期/Date（YYYYMMDD）     : 20200325
  程序目的/Purpose          :
  使用8266作为WebServer,并用浏览器打开设备IP+80端口进行访问
  在登录主页时使用认证方式登录,并从串口反馈请求头的信息
  -----------------------------------------------------------------------
  本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。
  该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：
  http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/
***********************************************************************/


#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>

//设置WiFi接入信息
const char* ssid = "TaichiMaker";
const char* password = "XXXXXXXX";

ESP8266WebServer server(80);

//设置需要收集的请求头信息
const char *headerKeys[] = {"Content-Length", "Content-Type", "Connection", "Date"};

// 设置主页请求处理函数
void homepage() {

  //校验用户登录账号和密码,(使用Basic方式),若输入错误则继续返回认证界面
  if (!server.authenticate("TaichiMaker", "123456")) return server.requestAuthentication();

  server.send(200, "text/plain", "test homepage");
  Serial.println("用户访问了主页");
  echo_headers();
}


// 设置处理404情况的函数'handleNotFound'
void handleNotFound() {                                       // 当浏览器请求的网络资源无法在服务器找到时，
  server.send(404, "text/plain", "404: Not found");           // NodeMCU将调用此函数。
  echo_headers();
}

void setup(void) {
  //初始化串口
  Serial.begin(115200);
  Serial.println("");

  //初始化网络
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("IP Address: ");
  Serial.println(WiFi.localIP());

  //初始化WebServer
  server.begin();
  //设置主页处理函数
  server.on("/", homepage);
  //设置404页面
  server.onNotFound(handleNotFound);
  //串口输出服务器准备完成信息
  Serial.println("HTTP server started");
  //设置需要收集的请求头信息
  server.collectHeaders(headerKeys, sizeof(headerKeys) / sizeof(headerKeys[0]));
}

void loop(void) {
  //监听客户请求并处理
  server.handleClient();
}

void echo_headers() {

  if (server.hasHeader("Connection")) {//判断该请求头是否存在

    //打印当前请求中所收集的请求头指定项的值
    Serial.print("当前请求所收集的请求头Connection:"); Serial.println(server.header("Connection"));

    //打印当前请求中所收集的Host
    Serial.print("当前请求所收集的请求头Host :"); Serial.println(server.hostHeader());
    //分隔空行
    Serial.println("\r\n");
  }
}

/**********************************************************************

项目名称/Project : 零基础入门学用物联网

程序名称/Program name : WebServer_demo_authenticate

团队/Team : 太极创客团队 / Taichi-Maker (www.taichi-maker.com)

作者/Author : Dapenson

日期/Date（YYYYMMDD） : 20200325

程序目的/Purpose :

使用8266作为WebServer,并用浏览器打开设备IP+80端口进行访问

在登录主页时使用认证方式登录,并从串口反馈请求头的信息

-----------------------------------------------------------------------

本示例程序为太极创客团队制作的《零基础入门学用物联网》中示例程序。

该教程为对物联网开发感兴趣的朋友所设计和制作。如需了解更多该教程的信息，请参考以下网页：

http://www.taichi-maker.com/homepage/esp8266-nodemcu-iot/

***********************************************************************/

#include <ESP8266WiFi.h>

#include <ESP8266WebServer.h>

//设置WiFi接入信息

const char* ssid = "TaichiMaker";

const char* password = "XXXXXXXX";

ESP8266WebServer server(80);

//设置需要收集的请求头信息

const char *headerKeys[] = {"Content-Length", "Content-Type", "Connection", "Date"};

// 设置主页请求处理函数

void homepage() {

//校验用户登录账号和密码,(使用Basic方式),若输入错误则继续返回认证界面

if (!server.authenticate("TaichiMaker", "123456")) return server.requestAuthentication();

server.send(200, "text/plain", "test homepage");

Serial.println("用户访问了主页");

echo_headers();

}

// 设置处理404情况的函数'handleNotFound'

void handleNotFound() { // 当浏览器请求的网络资源无法在服务器找到时，

server.send(404, "text/plain", "404: Not found"); // NodeMCU将调用此函数。

echo_headers();

}

void setup(void) {

//初始化串口

Serial.begin(115200);

Serial.println("");

//初始化网络

WiFi.mode(WIFI_STA);

WiFi.begin(ssid, password);

while (WiFi.status() != WL_CONNECTED) {

delay(500);

Serial.print(".");

}

Serial.println("");

Serial.print("IP Address: ");

Serial.println(WiFi.localIP());

//初始化WebServer

server.begin();

//设置主页处理函数

server.on("/", homepage);

//设置404页面

server.onNotFound(handleNotFound);

//串口输出服务器准备完成信息

Serial.println("HTTP server started");

//设置需要收集的请求头信息

server.collectHeaders(headerKeys, sizeof(headerKeys) / sizeof(headerKeys[0]));

}

void loop(void) {

//监听客户请求并处理

server.handleClient();

}

void echo_headers() {

if (server.hasHeader("Connection")) {//判断该请求头是否存在

//打印当前请求中所收集的请求头指定项的值

Serial.print("当前请求所收集的请求头Connection:"); Serial.println(server.header("Connection"));

//打印当前请求中所收集的Host

Serial.print("当前请求所收集的请求头Host :"); Serial.println(server.hostHeader());

//分隔空行

Serial.println("\r\n");

}

说明

语法

参数

返回值

示例程序

相关内容